Chip 1997 December/CHIP Turkiye Aralık 1997.iso/internet/lsmirc61.exe/raw.in_/raw.in

INI File | 1997-09-21 | 23.4 KB | 568 lines

[script]
n0=;  This section handles all raw codes from there server
n1=;
n2=alias censoredchan {
n3=  ; given channel name $1 and list of channels $2-, determine if there is any
n4=  ; channels that are unwanted
n5=  %n = 0
n6=  :nx
n7=  inc %n
n8=  if %cenchan [ $+ [ [ $1 ] [ $+ [ %n ] ] ] ] != $null {
n9=    if (%cenchan [ $+ [ [ $1 ] [ $+ [ %n ] ] ] ] isin $strip($2-)) return %cenchan [ $+ [ [ $1 ] [ $+ [ %n ] ] ] ]
n10=    goto nx
n11=  }
n12=  return $null
n13=}
n14=alias checkchans {
n15=  ; Given nick $1 and channel list $2-, determine if the person is in violation of
n16=  ; the channel name censor
n17=  %c = 0
n18=  :nx
n19=  inc %c
n20=  if $chan(%c) != $null {
n21=    if (($isop($1,$chan(%c))) || ($1 !ison $chan(%c))) goto nx
n22=    if ($me isop $chan(%c)) {
n23=      if (%haveoptions [ $+ [ $chan(%c) ] ] ) set %namecheck $chan(%c)
n24=      else set %namecheck other
n25=      if (%namecensor [ $+ [ %namecheck ] ] ) {
n26=        set %badchannel $censoredchan(%namecheck,$2-)
n27=        if %badchannel != $null {
n28=          if (%namecensorban [ $+ [ %namecheck ] ] ) { mode $chan(%c) +b-o $a3($1) $1 | rtb $a3($1) $chan(%c) }
n29=          kick $chan(%c) $1 Unwanted: members of channels with " $+ %badchannel $+ " in the name
n30=        }
n31=      }
n32=    }
n33=    goto nx
n34=  }
n35=}
n36=#invitenames off
n37=raw 353:*:{
n38=  ; mass invite a channel you're not even on
n39=  set %l 3
n40=  :nx
n41=  inc %l | set %name [ $+ [ %l ] ]
n42=  if %name = $null halt
n43=  invite %name %chan | goto nx
n44=  halt
n45=}
n46=raw 366:*:.disable #invitenames | altech -a %dis10 $+ Mass Invite complete | halt
n47=#invitenames end
n48=#gma off
n49=raw 302:*:{
n50=  if $2 = $null { set %me $me | userhost $me }
n51=  else { set %myadr $replace( [ $replace($2,=,!) ] ,+,*) | .disable #gma }
n52=  halt
n53=}
n54=#gma end
n55=#allwho off
n56=; do a /who, then a /whois on every match found (this is called from /swho,
n57=; like /swho *.netcom.com  (although I wouldn't do that one!)
n58=raw 352:*:whois $6 | inc %fwht | halt
n59=raw 315:*:{
n60=  .disable #allwho | .enable #nw
n61=  if %fwht = 0 altech -s %dis10 $+ No matches found for %fwho
n62=  elseif %ftht = 1 altech -s %dis10 $+ Found 1 match for %fwho
n63=  else altech -s %dis10 $+ Found %fwht match(es) for %fwho
n64=  halt
n65=}
n66=#allwho end
n67=#autoicmp off
n68=raw 302:*:{
n69=  .disable #autoicmp
n70=  set %adr $replace($2,=,!) | set %adr $replace(%adr,+,*)
n71=  set %pos $calc($pos(%adr,!) -1 )
n72=  set %icmpnick $left(%adr,%pos)
n73=  if $mask(%adr,3) iswm %myadr echo 3 -a %icmpnick is $mask(%adr,3) $+ ... your clone!
n74=  elseif $mask(%adr,2) iswm %myadr echo 3 -a %icmpnick is $mask(%adr,2) $+ ... your clone!
n75=  else {
n76=    echo 3 -a %icmpnick is $mask(%adr,3)
n77=    echo 4 -a Press F7 to ICMP %icmpnick | .timer 1 60 unset %icmpnick
n78=  }
n79=  halt
n80=}
n81=#autoicmp end
n82=#verifylamer off
n83=; verify that a nick is on IRC before sending a mock
n84=raw 302:*:{
n85=  .disable #verifylamer
n86=  if $2 = $null {
n87=    raw -q notice %tvmocker [ $+ [ %mockee ] ] : $+ %mockee is not on IRC you lamer!!!
n88=    altech #MockLamer %dis10 $+ %mockee is not on IRC, request ignored
n89=    dh
n90=  }
n91=  set %mockee $left($2,$calc($pos($2,=) - 1))
n92=  set %mocker %tvmocker [ $+ [ %mockee ] ]
n93=  set %insult $rinsult
n94=  raw -q notice %mockee :4 $+ %mockee $+ , you are a %insult 5(You were mocked at the request of %mocker $+ )
n95=  altech #MockLamer %dis10 $+ Mock Lamer: told %mockee he was a %insult
n96=  halt
n97=}
n98=#verifylamer end
n99=#verifylamer2 off
n100=; verify that a nick is on IRC before I send a mock so I don't look like an ass
n101=; by doing requests for nicks that don't exist
n102=raw 302:*:{
n103=  .disable #verifylamer2
n104=  if $2 = $null { altech -a %dis10 $+ %mockee is not on IRC, not sending mock lamer request | halt }
n105=  msg #MockLamer |mocklamer $left($2,$calc($pos($2,=) - 1))
n106=  halt
n107=}
n108=#verifylamer2 end
n109=#altadd off
n110=; attempt to add someone who is not in my ial to my userlist
n111=raw 302:*:{
n112=  .disable #altadd
n113=  if $2 = $null { altech -a %dis7 $+ %addnick is not on IRC, cannot add | dh }
n114=  else dde control $ddename adduser %addnick $convert($replace( [ $replace($2,=,!) ] ,+,*))
n115=  halt
n116=}
n117=#altadd end
n118=#revenge off
n119=raw 302:*:{
n120=  .disable #revenge
n121=  if $2 = $null { altech 4 -a %tvicmpnick is not on IRC!! | dh }
n122=  else {
n123=    set %addy $mask($replace( [ $replace($2,=,!) ] ,+,*),2)
n124=    set %len $calc($len(%addy) - 4)
n125=    if ($isnumericip($right(%addy,%len))) runicmp $right(%addy,%len)
n126=    else { .disable #regdns | .enable #revengedns | .dns %tvicmpnick }
n127=  }
n128=  halt
n129=}
n130=#revenge end
n131=#altfsb off
n132=; attempt to add someone who is not in my ial to my fileserver ban list
n133=raw 302:*:{
n134=  .disable #altfsb
n135=  if $2 = $null { altech -a %dis7 $+ %addfsb is not on IRC, cannot add | dh }
n136=  else addfsb $convert($replace( [ $replace($2,=,!) ] ,+,*)) %fsbreason
n137=  halt
n138=}
n139=#altfsb end
n140=#altban off
n141=; attempt to add someone who is on in my ial to my ban list
n142=raw 302:*:{
n143=  .disable #altban
n144=  if $2 = $null { altech -a %dis7 $+ %addnick is not on IRC, cannot add ban | dh }
n145=  else {
n146=    set %addy $replace( [ $replace($2,=,!) ] ,+,*)
n147=    if %banchan != $null {
n148=      kickbanall $mask(%addy,3) %banchan %default | rtb $mask(%addy,3) %banchan
n149=      dde control $ddename $+ addban mask $mask(%addy,3) $+ > $+ $mask(%addy,4) $+ > $+ %banchan
n150=    }
n151=    else dde control $ddename $+ addban mask $mask(%addy,3) $+ > $+ $mask(%addy,4) $+ >
n152=  }
n153=  halt
n154=}
n155=#altban end
n156=#altignore off
n157=; attempt to add someone who is on in my ial to my ignore list
n158=raw 302:*:{
n159=  .disable #altignore
n160=  if $2 = $null { altech -a %dis7 $+ %addnick is not on IRC, cannot add ignore | dh }
n161=  else {
n162=    set %addy $replace( [ $replace($2,=,!) ] ,+,*)
n163=    dde control $ddename $+ ignore ignore %addnick $mask(%addy,3) $mask(%addy,4)
n164=  }
n165=  halt
n166=}
n167=#altignore end
n168=#altrem off
n169=; attempt to remove someone (who is not in my ial) from my userlist
n170=raw 302:*:{
n171=  .disable #altrem
n172=  if $2 = $null {
n173=    ; the person is not on IRC, but if this nick is known, I can still remove him
n174=    altech -a %dis7 $+ %remnick is not on IRC | altech -a %dis6 $+ Attempting yet another method!!...
n175=    set %adr $readini $ul address [ [ %remnick ] $+ 1 ]
n176=    if %adr = $null altech -a %dis7 $+ Nope, can't find %remnick in your user list, can't remove (You can remove with the "User List Maintenance Utility")
n177=    else ru %remnick %adr
n178=  }
n179=  else ru %remnick $replace( [ $replace($2,=,!) ] ,+,*)
n180=  halt
n181=}
n182=#altrem end
n183=#stats off
n184=; compile channel/IRC info and report it to the channel/IRC info program
n185=raw 352:*: {
n186=  inc %info.0 | set %adr *!* $+ $3 $+ @ $+ $4
n187=  if + isin $7 inc %info.2 | if G isin $7 inc %info.3
n188=  if * isin $7 inc %info.4 | if @ isin $7 inc %info.1
n189=  set %lv $al(%adr) | if %lv = 1 halt
n190=  if %lv = 20 inc %info.6
n191=  elseif %lv = 40 { inc %info.7 | if @ !isin $7 inc %info.11 }
n192=  elseif %lv = 50 { inc %info.8 | if @ !isin $7 inc %info.11 }
n193=  elseif %lv = 60 { inc %info.9 | if @ !isin $7 inc %info.11 }
n194=  elseif %lv = 70 inc %info.10
n195=  halt
n196=}
n197=raw 367:*:inc %info.5 | halt
n198=raw 368:*:dde chaninfo $ddename $+ info txtInfo(5) %info.5 | halt
n199=raw 251:*:dde chaninfo $ddename $+ info txtIRC(0) $2- | halt
n200=raw 252:*:dde chaninfo $ddename $+ info txtIRC(1) $2- | halt
n201=raw 254:*:{
n202=  dde chaninfo $ddename $+ info txtIRC(2) $2-
n203=  set %got254 $true
n204=  if ((%got266) && (%got315)) .disable #stats
n205=  halt
n206=}
n207=raw 250:*:halt
n208=raw 255:*:halt
n209=raw 265:*:dde chaninfo $ddename $+ info txtIRC(3) $5 (max: $7 $+ ) | halt
n210=raw 266:*:{
n211=  dde chaninfo $ddename $+ info txtIRC(4) $5 (max: $7 $+ )
n212=  if ((%got254) && (%got315)) .disable #stats
n213=  set %got266 $true
n214=  halt
n215=}
n216=raw 315:*:{
n217=  if ((%got266) && (%got254)) .disable #stats
n218=  set %got315 $true
n219=  set %info.12 $chan($2).mode
n220=  if %info.12 = $null set %info.12 no modes set
n221=  %k = -1 | dec %info.10 | if %info.10 < 0 set %info.10 0
n222=  :nx
n223=  inc %k | if %info. [ $+ [ %k ] ] = $null set %info. [ $+ [ %k ] ] 0
n224=  if %k < 11 goto nx
n225=  %temp = ""
n226=  %k = -1
n227=  :nw
n228=  inc %k | set %temp %temp $+ %info. [ $+ [ %k ] ] @
n229=  if %k < 12 goto nw
n230=  dde chaninfo $ddename $+ info chandata %temp
n231=  unset %info.* | halt
n232=}
n233=#stats end
n234=#filterops off
n235=raw 352:*:set %tvfolast $6 | whois $6 | halt
n236=raw 315:*:set %tvfolastnick %tvfolast | halt
n237=raw 301:*:halt
n238=raw 311:*:halt
n239=raw 312:*:halt
n240=raw 313:*:{
n241=  if $gl($2) > 18 { inc %tvforec | halt }
n242=  inc %tvfocount
n243=  if (%tvfoban) { mode %tvfochan -o+b $2 $a3($2) | rtb $a3($2) %tvfochan }
n244=  kick %tvfochan $2 %ircopkick
n245=  halt
n246=}
n247=raw 317:*:halt
n248=raw 319:*:halt
n249=raw 318:*:{
n250=  if $2 = %tvfolastnick {
n251=    .disable #filterops
n252=    if ((%tvfocount = 0) && (%tvforec != 0)) altech %tvfochan %dis10 $+ Did not find any IRC ops on %tvfochan that are not in your userlist!
n253=    elseif %tvfocount = 0 altech %tvfochan %dis10 $+ Did not find any IRC ops on %tvfochan
n254=    elseif %tvfocount = 1 altech %tvfochan %dis10 $+ IRC Op filter scan complete, kicked 1 person
n255=    else altech %tvfochan %dis10 $+ IRC Op filter scan complete, kicked %tvfocount people
n256=    unset %tvfo*
n257=  }
n258=  halt
n259=}
n260=#filterops end
n261=#nw on
n262=raw 329:*:halt
n263=raw 352:*:{
n264=  altech -s %dis0 $+ $6 %dis2 $+ ( $+ $3 $+ @ $+ $4 $+ )
n265=  if ($6 = %botnick [ $+ [ $2 ] ] ) {
n266=    set %tvfb [ $+ [ $2 ] ] $true
n267=    set %ady *!* $+ $3 $+ @ $+ $4
n268=    if ($al(%ady) >= 60) {
n269=      if $6 isop $2 {
n270=        raw -q PRIVMSG %botnick [ $+ [ $2 ] ] :op %botpass [ $+ [ $2 ] ]
n271=        altech -a %dis10 $+ Requesting ops from $6
n272=      }
n273=      else altech -a %dis10 $+ I'm supposed to /msg $6 for ops, be $6 is not a channel op right now
n274=    }
n275=    else altech -a %dis10 $+ I'm supposed to /msg $6 for ops.  I see it, but I don't know the address $mask(%ady,3)
n276=  }
n277=  halt
n278=}
n279=raw 315:*:{
n280=  if (%tvfb [ $+ [ $2 ] ] != $true) && (%botnick [ $+ [ $2 ] ] != $null) {
n281=    altech -a %dis10 $+ I'm supposed to /msg %botnick [ $+ [ $2 ] ] for ops, but its not here
n282=  }
n283=  if (($left($2,1) = $chr(35)) || ($left($2,1) = 38)) set %updatedial [ $+ [ $2 ] ] $true
n284=  halt
n285=}
n286=#nw end
n287=#detmul on
n288=raw 352:*:{
n289=  altech -s %dis0 $+ $6 %dis2 $+ ( $+ $3 $+ @ $+ $4 $+ )
n290=  inc %conn [ $+ [ $4 ] ]
n291=  if ((%conn [ $+ [ $4 ] ] > %excclientsis) && (%nk [ $+ [ $4 ] ] != $null)) {
n292=    kball *!*@ $+ $4 %excclientsmsg
n293=    altech -a %dis3 $+ Excessive Connections Detected! %dis4 Kicking %nk [ $+ [ $4 ] ]
n294=    if (%sexc = ding) ding
n295=    elseif (%sexc = speak) speak excessive connections detected, kicking %nk [ $+ [ $4 ] ]
n296=    elseif (%sexc != none) splay %sexc
n297=  }
n298=  unset %nk [ $+ [ $4 ] ] | unset %conn [ $+ [ $4 ] ]
n299=  halt
n300=}
n301=raw 315:*:halt
n302=#detmul end
n303=#nukeinfoserver off
n304=raw 301:*:halt
n305=raw 311:*:halt
n306=raw 312:*:{
n307=  altech -a %dis1 $+ Server: $+ %dis42 $3
n308=  if $3 = $server { altech -a %dis1 $+ You are on $3 $+ !  Listing ports... | getports }
n309=  else {
n310=    altech -a %dis1 $+ *** You are not on $3
n311=    altech -a %dis1 $+ *** Press Shift-F2 to try a "/stats l" anyway
n312=    set %tvgetports $3
n313=  }
n314=  halt
n315=}
n316=raw 313:*:halt
n317=raw 317:*:halt
n318=raw 319:*:halt
n319=raw 318:*:.disable #nukeinfoserver | halt
n320=#nukeinfoserver end
n321=#aww off
n322=raw 301:*:altech -a %dis0 $+ *** Away: $+ %dis2 $3- | halt
n323=raw 311:*:{
n324=  ; go ahead ink...  change the displays :P
n325=  altech -a %dis0 $+ *** Whois Information for: %dis2 $+ $2
n326=  set %ady $3 $+ @ $+ $4 | set %lev $level($m( [ *!*@ $+ [ %ady ] ] ))
n327=  altech -a %dis0 $+ *** Address: %dis2 $+ %ady
n328=  altech -a %dis0 $+ ***áReal Name: %dis2 $+ $right($5-,$calc($len($5-) - 2)) | halt
n329=}
n330=raw 312:*:altech -a %dis0 $+ *** Server: %dis2 $+ $3 | halt
n331=raw 313:*:altech -a %dis0 $+ ***áIRC operator | halt
n332=raw 317:*:altech -a %dis0 $+ ***áIdle: $+ %dis2 $dur2($3) | halt
n333=raw 319:*:{
n334=  altech -a %dis0 $+ ***áChannels: %dis2 $+ $3-
n335=  checkchans $2 $3-
n336=  halt
n337=}
n338=raw 318:*:{
n339=  dec %donewhois
n340=  if (%donewhois <= 0) .disable #aww
n341=  if ((%lev != $null) && ($wordlevel(%lev) != $null)) {
n342=    altech -a %dis0 $+ *** Level: %dis2 $+ $wordlevel(%lev)
n343=    unset %lev
n344=  }
n345=  halt
n346=}
n347=#aww end
n348=raw 301:*:if ($2 != $me) altech -s %dis0 $+ Away: $+ %dis2 $3- | halt
n349=raw 305:*:{
n350=  .timer974 off
n351=  if $chan(0) != 0 ame is no longer away
n352=  .disable #page | unset %amsg
n353=  altech -a %dis10 $+ The server recognizes you are no longer away
n354=  speak welcome back
n355=  if (%lagcheck)  {
n356=    titlebar Little Star 6.1  $me on $server $+ : $+ $port  Lag: waiting for info
n357=    .timer101 0 120 getlag | getlag
n358=  }
n359=  else titlebar Little Star 6.1  $me on $server $+ : $+ $port
n360=  halt
n361=}
n362=raw 306:*:{
n363=  if (($usermodes = $null) || ($usermodes = +)) titlebar Little Star 6.1  $me on $server  AWAY 
n364=  else titlebar Little Star 6.1  $me %modes on $server  AWAY 
n365=  .timer101 off | altech -a %dis10 $+ The server has marked you as being away
n366=  speak you are now marked away. | halt
n367=}
n368=raw 315:*:halt
n369=raw 311:*:{
n370=  ; look ink!  here's some more /whois stuff!
n371=  altech -s %dis0 $+ Whois Information for: %dis2 $+ $2
n372=  set %ady $3 $+ @ $+ $4 | set %lev $level($m( [ *!*@ $+ [ %ady ] ] ))
n373=  altech -s %dis0 $+ Address: %dis2 $+ %ady
n374=  altech -s %dis0 $+ Real Name: $+ %dis2 $right($5-,$calc($len($5-) - 2)) | halt
n375=}
n376=raw 312:*:altech -s %dis0 $+ Server: %dis2 $+ $3 | halt
n377=raw 313:*:altech -s %dis0 $+ IRC operator | halt
n378=raw 314:*:{
n379=  ; if you changed the /whois stuff... change the /whowas stuff to match!
n380=  altech -s %dis0 $+ WhoWas Information for: %dis2 $+ $2
n381=  set %ady $3 $+ @ $+ $4 | set %lev $level($m( [ *!*@ $+ [ %ady ] ] ))
n382=  altech -s %dis0 $+ Address: %dis2 $+ %ady
n383=  altech -s %dis0 $+ Real Name: $+ %dis2 $right($5-,$calc($len($5-) - 2)) | halt
n384=}
n385=raw 315:*:altech -s %dis0 $+ End of WHO list for $2 | halt
n386=raw 317:*:altech -s %dis0 $+ Idle: $+ %dis2 $dur2($3) | halt
n387=raw 319:*:{
n388=  altech -s %dis0 $+ Channels: %dis2 $+ $3-
n389=  checkchans $2 $3-
n390=  halt
n391=}
n392=raw 318:*:if ((%lev != $null) && ($wordlevel(%lev) != $null)) { altech -s %dis0 $+ Level: %dis2 $+ $wordlevel(%lev) | unset %lev } | halt
n393=raw 324:*:{
n394=  if $3 = + set %mode no modes set
n395=  else set %mode $3
n396=  altech -s %dis40 $+ Mode for $2 $+ : %dis41 $+ %mode | halt
n397=}
n398=#getports off
n399=raw 211:*:{
n400=  if $pos($1-,*.) != $null {
n401=    inc %tvports
n402=    addport %dis10 $mid($2,$calc(($pos($2,*.) + 2)), $calc(($pos($2,])) - $calc(($pos($2,*.) + 2))))
n403=    ; that's about as ugly as a line of code can get... go ahead, figure it out :P
n404=  }
n405=  elseif $pos($1-,0.) != $null {
n406=    inc %tvports
n407=    addport %dis10 $mid($2,$calc(($pos($2,0.) + 8)), $calc(($pos($2,])) - $calc(($pos($2,0.) + 8))))
n408=  }
n409=  halt
n410=}
n411=raw 219:*:{
n412=  if %tvports = $null set %tvports 0
n413=  addport %dis10 $+ Total ports available: %tvports
n414=  unset %tvports | .disable #getports | halt
n415=}
n416=#getports end
n417=raw 331:*:echo -s %dis10 $+ No topic is set for $2 | halt
n418=raw 332:*:echo -s %dis1 $+ Topic for $2 $+ : %dis42 $+ $3- | halt
n419=raw 333:*:echo -s %dis1 $+ Topic set by: %dis42 $+ $3 | halt
n420=raw 341:*:echo -s %dis10 $+ $2 has been invited to $3 | halt
n421=raw 352:*:echo -s %dis0 $+ $6 %dis2 $+ ( $+ $3 $+ @ $+ $4 $+ ) %dis0 $+ on $2 | halt
n422=raw 353:*:echo -s %dis40 $+ Names list for $3 $+ : $+ %dis41 $4- | halt
n423=raw 366:*:halt
n424=raw 369:*:halt
n425=raw 375:*:halt
n426=raw 376:*:halt
n427=raw 381:*:echo -a %dis10 $+ You are now an IRC op | if (%opdedicated) openopwindow | halt
n428=raw 401:*:{
n429=  if (%urd) { z | echo 4 $me $2 $+ : no such nick }
n430=  else echo -a %dis0 $+ $2 $+ : no such nick
n431=  .disable #nukeinfoserver #aww | halt
n432=}
n433=raw 402:*:echo -a %dis1 $+ No such nick: %dis42 $+ $2 | .disable #aww #nukeinfoserver | halt
n434=raw 403:*:echo -a %dis1 $+ No such channel: %dis42 $+ $2 | halt
n435=raw 404:*:echo -s %dis10 $+ Cannot send text to channel (it's moderated or you are desynched) | halt
n436=raw 405:*:echo -s %dis10 $+ Cannot join $2 $+ .  You have joined too many channels already! | halt
n437=raw 406:*:echo -a %dis1 $+ There was no such nickname: %dis42 $+ $2 | halt
n438=raw 421:*:echo -s %dis10 $+ Error: " $+ $2 $+ " is an invalid command | halt
n439=raw 432:*:echo -s %dis10 $+ $2 is an erroneous nickname! | halt
n440=raw 433:*:{
n441=  if $2 = ElmerFudd { echo -s %dis10 $+ ElmerFudd nick is already in use. | echo -s %dis10 $+ Cannot perform action kick | .disable #ak | halt }
n442=  if $2 = %tvawaynick { echo -s %dis10 $+ %tvawaynick is already in use, cannot change nicks | unset %tvawaynick | unset %tvsettingaway | setaway %awayreason | halt }
n443=  if (%underscore) {
n444=    set %newnick $2 $+ _
n445=    if ($me != %newnick) {
n446=      if (($len(%newnick) > 9) && (dal.net !isin $server)) {
n447=        altech -s %dis10 $+ Nickname $2 is already in use!
n448=        altech -s %dis10 $+ Cannot try %newnick $+ , it's too long
n449=        halt
n450=      }
n451=      altech -s %dis10 $+ Nickname $2 in use, trying %newnick
n452=      nick %newnick
n453=    }
n454=  }
n455=  elseif ($notimer(930)) { echo 4 -s Nickname $2 is already in use! | whois $2 }
n456=  halt
n457=}
n458=raw 436:*:echo -s %dis10 $+ Acckkkk! Nick Collision! | halt
n459=raw 438:*:echo -s %dis10 $+ $server $+ : $3-
n460=raw 441:*:echo -a %dis10 $+ $2 is not on $3 $+ ! | halt
n461=raw 442:*:echo -a %dis10 $+ You are not on $2 | halt
n462=raw 443:*:echo -a %dis10 $+ $2 is already on $3 $+ ! | halt
n463=raw 461:*:echo -a %dis10 $+  You must specify a limit when setting +l, like +l 50 | halt
n464=raw 464:*:echo -a %dis10 $+ Password Incorrect! | halt
n465=raw 465:*:echo -s %dis10 $+ $2- | halt
n466=raw 467:*:halt
n467=raw 471:*:echo -a %dis10 $+  Cannot join $2 (Channel is full) | halt
n468=raw 472:*:echo -a %dis1 Incorrect Character: %dis42 $+ $2 | halt
n469=raw 473:*:echo -a %dis10 $+ Cannot join $2 $+ , it's invite only! | halt
n470=raw 475:*:echo -a %dis1 $+ $2 $+ : %dis42 $+ channel requires correct key to enter. | halt
n471=raw 474:*:{
n472=  echo -a %dis12 $+ You can't join $2 $+ , you're banned!
n473=  ; did I just check to see what ban masks match my address?
n474=  if (%tviknowimbanned [ $+ [ $2 ] ] ) halt
n475=  ; if not, go ahead and check
n476=  echo -a %dis13 $+ Retrieving info on bans against you...
n477=  set %bc 0 | unset %wbm* | .enable #wbm | mode $2 b | halt
n478=}
n479=raw 478:*:if $me isop $2 onotice $2 The channel ban list is now full! | echo -a %dis10 $+ Ban list for $2 is full! | dh
n480=raw 481:*:echo -a %dis10 $+ You are not an IRC operator! | halt
n481=raw 482:*:{
n482=  if $left($2,1) = $chr(35) echo -a %dis10 $+ You are not a channel op on $2 $+ !
n483=  else echo -a %dis10 $+ $2-
n484=  halt
n485=}
n486=raw 483:*:echo -a %dis10 $+ You can't kill the server! | halt
n487=raw 501:*:echo -s %dis10 $+ Unkown MODE flag! | halt
n488=raw 502:*:echo -s %dis10 $+ You cannot change modes for other users! | halt
n489=#clearbans off
n490=raw 367:*:inc %rtbans | set %rtban [ $+ [ %rtbans ] ] $3 | halt
n491=raw 368:*:{
n492=  .disable #clearbans #wbm
n493=  unset %bans | %i = 0
n494=  :nx
n495=  inc %i
n496=  if (%rtban [ $+ [ %i ] ] = $null) { if $len(%bans) > 0 mode %chan -bbbb %bans | halt }
n497=  set %bans %bans %rtban [ $+ [ %i ] ]
n498=  if %maxmodes // %i { mode %chan -bbbb %bans | %bans = "" }
n499=  goto nx
n500=  :nx
n501=  echo -a %dis10 $+ Removed %rtbans ban(s) on %chan | unset %chan | unset %rtban* | halt
n502=}
n503=#clearbans end
n504=#wbm off
n505=raw 367:*:{
n506=  ; hey, a ban mask that matches my address
n507=  if $3 iswm %myadr {
n508=    inc %bc
n509=    set %wbmw [ $+ [ %bc ] ] $left($4,$calc($pos($4,!) - 1)) ( $+ $mask($4,3) $+ ) at $asctime($5)
n510=    set %wbmm [ $+ [ %bc ] ] $3
n511=  }
n512=  halt
n513=}
n514=raw 368:*:{
n515=  .disable #wbm #clearbans
n516=  if %bc = 0 { echo -a %dis14 $+ Could not find the ban that matches your hostmask | unset %wb* | halt }
n517=  if %bc = 1 echo -a %dis14 $+ There is 1 ban on $2 against you:
n518=  else echo -a %dis14 $+ There are %bc bans on $2 against you:
n519=  %i = 0
n520=  :nx
n521=  inc %i
n522=  if %wbmm [ $+ [ %i ] ] != $null {
n523=    echo -a %dis13 $+ Ban: %wbmm [ $+ [ %i ] ]
n524=    echo -a %dis13 $+ Set by: %wbmw [ $+ [ %i ] ]
n525=    goto nx
n526=  }
n527=  set %tviknowimbanned [ $+ [ $2 ] ] $true
n528=  unset %wb* | halt
n529=}
n530=#wbm end
n531=raw 367:*:{
n532=  inc %tvnumban [ $+ [ $2 ] ]
n533=  echo -a %dis1 $+ ----- %dis42 $+ $2 Ban %dis1 $+ -----
n534=  echo -a %dis1 $+ Ban: %dis42 $+ $3
n535=  echo -a %dis1 $+ Set by: %dis42 $+ $left($4,$calc($pos($4,!) - 1)) ( $+ $mask($4,3) $+ )
n536=  echo -a %dis1 $+ Set at: %dis42 $+ $asctime($5) | halt
n537=}
n538=raw 368:*:{
n539=  if (%tvnumban [ $+ [ $2 ] ] = $null) echo -a %dis10 $+ There are no bans on $2
n540=  elseif (%tvnumban [ $+ [ $2 ] ] = 1) echo -a %dis10 $+ End of Ban List for $2 (1 ban found)
n541=  else echo -a %dis10 $+ End of Ban List for $2 ( $+ %tvnumban [ $+ [ $2 ] ] bans found)
n542=  unset %tvnumban [ $+ [ $2 ] ]
n543=  halt
n544=}
n545=raw 251:*:echo -a %dis20 $+ Users: $+ %dis21 $2- | halt
n546=raw 252:*:echo -a %dis20 $+ IRC Ops: %dis21 $+ there are $2- | halt
n547=raw 254:*:echo -a %dis20 $+ Channels: %dis21 $+ there are $2- | halt
n548=raw 250:*:echo -a %dis20 $+ $2- | halt
n549=raw 255:*:halt
n550=raw 265:*:echo -a %dis20 $+ Current local users: $+ %dis21 $5 %dis20 $+ (max: $+ %dis21 $7 $+ %dis20 $+ ) | halt
n551=raw 266:*:echo -a %dis20 $+ Current global users: $+ %dis21 $5 %dis20 $+ (max: $+ %dis21 $7 $+ %dis20 $+ ) | halt
n552=raw 302:*:{
n553=  if $2 = $null halt
n554=  else {
n555=    set %nick $left($2,$calc($pos($2,=) - 1))
n556=    if %nick = $me halt
n557=    if (%tvnotify [ $+ [ %nick ] ] != $true) halt
n558=    set %addy $replace( [ $replace($2,=,!) ] ,+,*)
n559=    set %level $wordlevel2($al(%addy))
n560=    if %level = $null altech -a %dis1 $+ *** $left($2,$calc($pos($2,=) - 1)) is on IRC %dis42 $+ ( $+ $mask(%addy,1) $+ ) (unknown address)
n561=    else altech -a %dis1 $+ *** $left($2,$calc($pos($2,=) - 1)) ( $+ %level $+ ) is on IRC %dis42 $+ ( $+ $mask(%addy,1) $+ )
n562=    ; gotta love what adding a/v options did to these once simple /echo commands!
n563=  }
n564=  halt
n565=}